序列+迭代练习
20260713 建立
研习自：geogebra基础入门22： 序列、迭代、映射大比拼（2017南京高考一模）
学习心得：
#方法二：邓兵老师的映射方法
n=Slider(1,20,1)
赋值(n,6)
Nums=1...n
f:y=(x+1)/sqrt(3)
#绘制多个正多边
Tris=映射(多边形((2^(ppp - 1) - 1, 0), (2^ppp - 1, 0), 3), ppp, Nums)
#绘制l2为A系列点，l3为B系列点，
As=映射((2^(ppp - 1) - 1, 0), ppp, Nums)
Bs=映射((3 / 2 * 2^(ppp - 1) - 1, sqrt(3) / 2 * 2^(ppp - 1)), ppp, Nums)
#这两个序列+文本指令，而且对点AB的位置进行了微调，非常实用！
#l6=序列(文本("B_{" + (i) + "}", Bs(i) + 单位法向量(f) / 2), i, 1, n, 1)
BT2=序列(文本("B_{" + (i) + "}", Bs(i) + (0, 1)), i, 1, n, 1)
AT2=序列(文本("A_{" + (i) + "}", As(i) + (0, -0.5)), i, 1, n, 1)
#方法三：赵林和桂群成老师的迭代+位似方法
f:y=(x+1)/sqrt(3)
A_1=(0,0)
A_2=(1,0)
poly3=多边形(A_1,A_2,3)
#得到的一系列的正三角形
Tris3=迭代列表(位似(p, 2, (-1, 0)), p, {poly3}, n)
#得到的一系列的B,A
B_1=交点(直线(A_1,(1,sqrt(3))),f)
Bs3=迭代列表(位似(p, 2, (-1, 0)), p, {B_1}, n)
As3=迭代列表(位似(p, 2, (-1, 0)), p, {A_1}, n)
#得到的一系列的B,A的名称文本，批量命名
BT3=序列(文本("B_{" + (i) + "}", Bs3(i) + 单位法向量(f) / 2), i, 1, n, 1)
AT3=序列(文本("A_{" + (i) + "}", As3(i) + (0, -0.5)), i, 1, n, 1)
#方法四：朱亮老师的序列+位似方法
α=30°
h:y=tan(α)(x+1)
A=(-1,0)
A_1=(0,0)
A_2=(1,0)
poly3=多边形(A_1,A_2,3)
Tris4=序列(位似(poly3, (距离(A,A_2)/ 距离(A,A_1))^k, A), k, 1, n)
#方法五：孙生富老师的迭代+序列方法
#n = 6
#的到一系列点B、A
AB5=合并(迭代列表(位似(p, 2, (-1, 0)), p, {{(0, 0), (1; π / 3)}}, n))
ABs5=迭代列表(位似(p, 2, (-1, 0)), p, {{(0, 0), (1; π / 3)}}, n)
#这两个指令的效果相同，都是对点AB进行标注l3非常巧妙利用取余函数进行判断，添加文本标注
ABT5=序列(如果(取余(k, 2) ≟ 0, 文本("A_{" + (k + 1) + "}", AB5(k + 1) - (0, 0.2)), 文本("B_{" + (k + 1) + "}", AB5(k + 1) + (0, 0.2))), k, 0, n)
ABTs5=序列(映射(文本(p "_{" + (i) + "}", q), q, ABs5(i), p, {"A", "B"}), i, 1, n + 1)
Seg=折线(AB5)
#方法六：周丙臻 老师的函数法
ff(x)=sqrt(3)/3*(x+1)
uu(x)=if(x>=0,-sqrt(3)*abs(x-1.5*2^floor(log(2,x+1))+1)+2^floor(log(2,x+1))*0.5*sqrt(3))
gg(x)=0.5*sqrt(3)*2^floor(log(2,x+1))
hh(x)= x+1-2^floor(log(2,x+1.5))
BBB=交点(gg,ff,0,n)
AAA=roots(hh,0,n)
#周老师说：把上面的所有代码一次性粘贴到，ggb的按钮脚本中，就可以得到图形；我这个脚本是求交点系统自动生成的。floor与log的配合容易想到，其实在绘图之前，我打了下草稿，这里给出折线函数的复合函数形式，分成三个函数应该好理解不少。
#g(x)=0.5*2^floor(log(2,x+1))
#h(x)=1.5*2^floor(log(2,x+1))-1
#u(x)=-sqrt(3)*abs(x-h(x))+g(x)*sqrt(3)